İçerikler

# Basic'ten Python Betiklerini Çağırmak

Phyton betiklerini LibreOffice Basic makrosundan çağırmak mümkündür, ve şunlar gibi değerli özellikler edinilebilir:

- ComputerName tanımlama ya da OSName tespiti mümkündür,

- Basic FileLen() function and com.sun.star.ucb.SimpleFileAccess.getSize() API function exhibit a 2 Gigabytes file size upper limit that Python helps to overcome,

- com.sun.star.util.PathSettings normalleştirilebilir,

- ve daha fazlası.

A reasonable exposure to LibreOffice Basic and to Application Programming Interface (API) features is recommended prior to perform inter-language calls from Basic to Python, to JavaScript or any other script engine.

## Python Betiklerini Almak

Python betikleri kişisel olabilir, paylaşılabilir veya belgelere gömülebilir. Bunları yürütmek için, LibreOffice Basic'e Python betiklerinin konumlarının sağlanması gerekir.com.sun.star.script.provider.XScript arayüzü uyumlu UNO nesnelerinin konumlandırılması Python betiklerinin yürütülmesini sağlar:

             Option Explicit

             Public Function GetPythonScript(macro As String, _
                     Optional location As String) As com.sun.star.script.provider.Xscript
                 Python betik nesnesini yürütmeden önce '''yakala
                 ' Argümanlar:
                 '    macro   : as "library/module.py$macro" or "module.py$macro"
                 '    location: as "document", "share", "user" or ENUM(eration)
                 'Sonuç:
                 '    located com.sun.star.script.provider.XScript UNO service'''
                 If IsMissing(location) Then location = "user"
                 Dim mspf As Object ' com.sun.star.script.provider.MasterScriptProviderFactory
                 Dim sp As Object ' com.sun.star.script.provider.XScriptProvider compatible
                 Dim uri As String
                 If location="document" Then
                     sp = ThisComponent.getScriptProvider()
                 Else
                     mspf = CreateUnoService("com.sun.star.script.provider.MasterScriptProviderFactory")
                     sp = mspf.createScriptProvider("")
                 End If
                 uri = "vnd.sun.star.script:"& macro &"?language=Python&location="& location
                 GetPythonScript = sp.getScript(uri)
             End Function ' GetPythonScript

## Executing Python Scripts

LibreOffice Uygulama Programlama Arayüzü (API) Komut Dosyası Çerçevesi, Python ile Basic veya bu konuda desteklenen diğer programlama dilleri arasında diller arası komut dosyası yürütmeyi destekler. Bağımsız değişkenler, her iki dilin de tanıdığı ilkel veri türlerini temsil etmeleri koşuluyla ve Komut Dosyası Çerçevesinin bunları uygun şekilde dönüştürdüğü varsayılarak çağrılar arasında aktarılabilir.

### Söz Dizimi

workstation_name = script.invoke(Array(), Array(), Array())

opSysName = script.invoke(Array(), in_outs, Array()) ' in_out is an Array

file_len = script.invoke(Array(systemFilePath), Array(), Array())

normalizedPath = script.invoke(Array(systemFilePath), Array(), Array())

### Gömülü Betik Örnekleri

Below ComputerName, and GetFilelen routines are calling their Python counterparts, using aforementioned GetPythonScript function. Exception handling is not detailed.

             Option Explicit
             Option Compatible ' Properties are supported

             Private scr As Object ' com.sun.star.script.provider.XScript

             Private Property Get ComputerName As String
                 '''İş istasyonu adı''
                 scr = GetPythonScript("Platform.py$computer_name", "document")
                 ComputerName = scr.invoke(Array(), Array(), Array())
             End Property ' ComputerName

             Private Function GetFilelen(systemFilePath As String) As Currency
                 '''Bayt cinsinden dosya boyutu'''
                 scr = GetPythonScript("Os/Path.py$get_size", Script.ISEMBEDDED)
                 GetFilelen = scr.invoke(Array(systemFilePath), Array(), Array(),)
             End Function ' GetFilelen

             Private Type _SCRIPT_LOCATION
                 ISEMBEDDED As String ' document script
                 ISPERSONAL As String ' user script
                 ISSHARED As String ' LibreOffice macro
             End Type ' _SCRIPT_LOCATION

             Public Function Script() As Object ' Text enumeration
                 Static enums As _SCRIPT_LOCATION : With enums
                 If .ISEMBEDDED = "" Then
                     .ISEMBEDDED = "document" ' document script
                     .ISPERSONAL = "user" ' user scripts
                     .ISSHARED = "share" ' LibreOffice macro
                 End If : End With ' enums
                 Script = enums
             End Function ' Script

Two different Python modules are called. They can either be embedded in the current document, either be stored on the file system. Argument type checking is skipped for clarity:

- Platform.py

             # -*- coding: utf-8 -*-
             from __future__ import unicode_literals

             import platform

             def computer_name() -> str:
                 return platform.node()

             def OSname() -> str:
                 return platform.system()

- Os/Path.py

             # -*- coding: utf-8 -*-
             from __future__ import unicode_literals

             import os.path

             def get_size(systemFilePath: str) -> str:
                 return str(os.path.getsize(systemFilePath))

             def normalyze(systemPath: str) -> str:
                 return os.path.normpath(systemPath)

### Personal or Shared Scripts Examples

The calling mechanism for personal or shared Python scripts is identical to that of embedded scripts. Library names are mapped to folders. Computing LibreOffice user profile and shared modules system file paths can be performed as detailed in Getting session information. Below OSName, HelloWorld and NormalizePath routines are calling their Python counterparts, using aforementioned GetPythonScript function. Exception handling is not detailed.

             Option Explicit
             Option Compatible ' Properties are supported

             Private scr As Object ' com.sun.star.script.provider.XScript

             Private Property Get OSName As String
                 '''Platform name as "Linux", "Darwin" or "Windows"'''
                 scr = GetPythonScript("Platform.py$OSname", Script.ISPERSONAL)
                 OSName = scr.invoke(Array(), Array(), Array())
             End Property ' OSName

             Private Sub HelloWorld()
                 '''LibreOffice Python shared sample'''
                 scr = GetPythonScript("HelloWorld.py$HelloWorldPython", Script.ISSHARED)
                 scr.invoke(Array(), Array(), Array(),)
             End Sub ' HelloWorld

             Public Function NormalizePath(systemFilePath As String) As String
                 '''Strip superfluous '\..' in path'''
                 scr = GetPythonScript("Os/Path.py$normalyze", "user")
                 NormalizePath = scr.invoke(Array(systemFilePath), Array(), Array())
             End Function ' NormalizePath

## Python standard modules

LibreOffice embedded Python contains many standard libraries to benefit from. They bear a rich feature set, such as but not limited to:

- argparse Parser for command-line options, arguments and sub-commands

- cmath Mathematical functions for complex numbers

- csv CSV files reading and writing

- datetime Genuine date and time types

- json JSON encoder and decoder

- math Mathematical functions

- re Regular expression operations

- socket Low-level networking interface

- sys System-specific parameters and functions

- unittest and trace Unit testing framework and Track Python execution

- xml.etree.ElementTree ElementTree XML API

İlgili Konular

Python'dan Temel Makroları Çağırma

LibreOffice Basic Help

LibreOffice Python Betik Yardımı